microtom.net tom's windows tech blog

@ECHO OFF
 
SET FBPublishRange=%1
SET FBUpdateSecs=%2
 
IF NOT DEFINED FBPublishRange (
  SET FBPublishRange=6
  )
IF %FBPublishRange% LSS 1 (
  GOTO :HELP)
IF %FBPublishRange% GTR 12 (
  GOTO :HELP)
 
IF NOT DEFINED FBUpdateSecs (
  SET FBUpdateSecs=1800
  )
IF %FBUpdateSecs% LSS 1800 (
  GOTO :HELP)
IF %FBUpdateSecs% GTR 7200 (
  GOTO :HELP)
 
ECHO Updating Outlook Free Busy Options  
ECHO  Updating FBPublishRange using value %FBPublishRange%
reg add HKCU\Software\Microsoft\Office\11.0\Outlook\Preferences /t REG_DWORD /v FBPublishRange /d %FBPublishRange% /f>NUL
ECHO  Updating FBUpdateSecs using value %FBUpdateSecs%
reg add HKCU\Software\Microsoft\Office\11.0\Outlook\Preferences /t REG_DWORD /v FBUpdateSecs /d %FBUpdateSecs% /f>NUL
IF %ERRORLEVEL% EQU 0 (
	ECHO Update Completed Successfully
  GOTO :EOF
	) ELSE (
	ECHO There was an error updating Outlook Free Busy Options. Return Value: %ERRORLEVEL%
	GOTO :EOF
	)
:HELP
ECHO.
ECHO Invalid Arguments Found
ECHO ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
ECHO.
ECHO Allows 2 optional arguments: [FBPublishRange] and [FBUpdateSecs]
ECHO.
ECHO Argument 1 specifies the number of months to publish Free/Busy information
ECHO   Valid values for argument 1 (FBPublishRange): 1 to 12
ECHO.
ECHO Argument 2 specifies the update interval to publish Free/Busy information
ECHO   Valid values for argument 2 (FBUpdateSecs): 1800 to 7200
ECHO.
ECHO Examples:
ECHO.
ECHO "UpdateOutlookFreeBusy.cmd" Uses default values 
ECHO   -FBPublishRange = 6, FBUpdateSecs = 1800
ECHO.
ECHO "UpdateOutlookFreeBusy.cmd 9"
ECHO   -FBPublishRange = 9, FBUpdateSecs = 1800
ECHO.
ECHO "UpdateOutlookFreeBusy.cmd 9 2400"
ECHO   -FBPublishRange = 9, FBUpdateSecs = 2400
GOTO :EOF
 
:EOF